Caro Passageiro:
Penso que se referia ao extracto de programação do indicador "CemTrend3" que hoje deixei na resposta ao amigo et.
Vamos lá tentar explicar em termos mais simples:
- No "Indicator Builder", depois de chamado para criar o novo indicador, aparece um quadro branco em que colocamos linha a linha o conjunto de instruções de programação:
auxrvi:=
If(
RVI(14)>56,1,
If(RVI(14)<44,-1,
PREV));
avgpvt16:=
Mov(PVT(),16,W);
auxpvt:=
If(
avgpvt16>Ref(avgpvt16,-1),1,
-1);
avgdmi10:=
Mov(Mov(DMI(C),10,W),3,S);
auxdmi:=
If(
Ref(avgdmi10,-1)-avgdmi10<0.1*(Ref(avgdmi10,-2)-Ref(avgdmi10,-1)),1,
-1);
auxtotal:=
auxrvi+auxpvt+auxdmi;
auxsinal:=
If(auxtotal=3,1,
If(auxtotal=-3,-1,
PREV));
auxsinal;
- O que quer isto dizer? Vamos lá então tentar decifrar de forma simples:
1) A linha 1 introduz uma variável a que chamamos "auxrvi", o que significa o indicador auxiliar baseado no indicador RVI que já vem no pacote de indicadores pré-definidos do Metastock. Tens de acrescentar na mesma sequência ao nome da variável os símbolos ":=" para definir a fórmula da variável "auxrvi".
2)Introduzes uma condição "If" condicional: Se o indicador RVI de 14 sessões for superior a 56 a variável "auxrvi" assume internamente o valor +1, se for inferior a 44 a variável interna "auxrvi" assume o valor -1 e se o RVI(14) estiver compreendido entre 44 e 56 não há alterações da variável "auxrvi" em relação ao cálculo assumido na sessão anterior.
No final da fórmula que define a variável "auxrvi" temos de colocar o símbolo ";" para passar ao conjunto de instruções seguinte.
3) Na 6ª linha é definida uma nova variável "avgpvt" à qual deves da mesma forma acrescentar os símboços ":=" para definir a fórmula que se irá seguir.
4) A fórmula que define o valor da variável "avgpvt" não é mais nem menos que a média pesada de 16 sessões do indicador pré-definido PVT() que significa "Price Volume Trend" que é uma linha acumulada que multiplica o volume do dia pela diferença entre o fecho de hoje e ontem. Se o mercado subiu, a linha do PVT sobe, se desceu a linha do PVT desce também. No fundo é uma linha igual à evolução das cotações mas ponderadas de acordo com o volume do dia.
5) Esta variável "avgpvt" é uma variável intermédia que precisamos para calcular uma nova variável interna que definimos como "auxpvt" que é calculada através de nova condição "If" que compara o valor da variável intermédia "avgpvt" da sessão actual com o valor da sessão anterior: se a "avgpvt" actual é superior à da sessão anterior atribuímos o valor +1 a "auxpvt" e se for igual ou inferior a variável "auxpvt" toma o valor -1.
6) Finalmente definimos uma nova variável chamada "auxdmi" que necessita previamente do cálculo intermédio de uma média lenta "avgdmi10" do indicador pré-definido DMI ( dynamic Momentum Index), mais concretamernte a média simples de 3 sessões de uma média de si mesma de 10 sessões pesadas.
7) Depois de definidas as condições de oscilação mais favoráveis para assumir os valores +1 ou -1 na variável "auxdmi", resta no final definir uma variável resumida "auxtotal" que representa o somatório das 3 variáveis calculadas pelo programa "auxrvi", "auxpvt" e "auxdmi". Quando a sua soma der +3 uma nova variável chamada "auxsinal" toma o valor +1, se a soma de "auxtotal" der -3 a variável "auxsinal" passa a ser -1 e se a soma de "auxtotal" der valores intermédios entre -3 e +3, o valor da sessão anterior continua a subsistir para o cálculo de "auxsinal".
8) Finalmente, para que seja impresso no gráfico o valor da variável "auxsinal", temos de introduzir a última linha em que chamamos a variável "auxsinal" terminando a instrução com um símbolo ";".
9) Ao chamar no Metastock o indicador "CemTrend3", o título que dei a este indicador, aparece o gráfico das cotações acompanhado pela visão da variável "auxsinal" do programa.
E pronto, espero ter esclarecido o amigo Passageiro da forma que achei mais simples.
Continuação de Boas Festas,
Cem
O Clubeinvest.com informa que nenhuma da informação
aqui facultada deverá ser entendida como conselho ou recomendação
de qualquer tipo de transacção ou investimento.
